HP49

Il n'existe pas d'instruction préprogrammée pour étudier les suites récurrentes. Pour exécuter plusieurs fois de suite une seule itération :
En mode algebrique
- on tape la valeur initiale
- on tape par exemple COS(ANS(1))/2 ENTER
- puis ENTER effectue à nouveau la même commande donc effectue une itération.
On peut aussi bien sûr définir une fonction de la façon suivante :
On tape DEF(F(X)=COS(X)/2)
on écrira alors F(ANS(1)) ENTER etc

On peut également écrire un programme, pour simplifier on va supposer que la fonction à itérer est stockée dans la variable F et la tolérance dans la variable EPS. On saisit la valeur de EPS, par exemple:
0.0001 STO> EPS (STO> s'obtient en appuyant sur la touche STO>).
et on tape le programme suivant (pour saisir le séparateur d'instruction ; tapez simultanément sur le shift-rouge et la touche SPC)

<< -> X N                 @ 2 arguments: u_0, nb max d'iterations
  << 0. -> I              @ variable locale compteur d'iteration
     << 
       DO
         STO+(1.,'I') ;   @ incremente le compteur d'iteration
         F(X) STO> X  ;   @ u_{i+1}=f(u_i)
       UNTIL
         ABS(F(X)-X)<EPS OR N<I  @ test d'arret
       END ;
       IF N<I THEN "Non trouve" ELSE ->TAG(X,I) END
     >>
   >>
>> -> ITER

Pour exécuter le programme, tapez par exemple: ITER(0.,30.)
où 0. est la valeur initiale de la suite et 30. est le nombre maximal d'iterations sur la pile. Le programme renvoie $u_i$ ou affiche un message en cas de non succès (plus de 30 itérations).
Voici aussi la version RPN¹ de ce programme qui est plus rapide et s'exécute aussi sur les HP48 (saisir le texte suivant puis entrez les deux arguments $u_0$ et $n$ maximal puis tapez ITER)

<<                       @ X N
   0. -> N I
   << 
     DO                  @ X
       1. 'I' STO+       @ X (incremente le compteur I)
       DUP F             @ X F(X)
       SWAP OVER -       @ F(X) X-F(X)
     UNTIL
       ABS EPS <         @ F(X) ?
       I N > OR
     END
     IF 
       I N > 
     THEN 
       "Non trouve" MSGBOX
     END
   >>                   @ F(X)
>> 'ITER' STO