Le puzzle de Dudeney Renée De Graeve 2017

Contents

• 1  Introduction
• 2  Les 4 pièces du puzzle
• 3  Le pavage correspondant au puzzle de Dudeney
• 4  Pour animer la transformation
• 5  Prolongement : transformer un carré en un triangle isocèle
• 6  Prolongement : transformer un rectangle en un triangle équilatéral
  • 6.1  Valeur de $l$ pour transformer un rectangle $2c\times 2a$ en un triangle équilatéral
  • 6.2  Les conditions sur $a$ et $c$
  • 6.3  La transformation

1  Introduction

Les quatre pièces du puzzle de Dudeney permettent de construire un carré ou un triangle équilatéral. L’animation 1 ci-dessous l’illustre, appuyer sur + puis sur - pour passer de l’un à l’autre.

Ernest Dudeney (1857-1930) a montré ce puzzle en 1905 lors d’une séance à la Royal Society à Londres. Sur ce modéle nous avons réalisé ici d’autres puzzles de 4 pièces qui transforment

1. un carré en un triangle équilatéral (ci-dessus)
2. un carré en un triangle isocèle (animation 2 ci-dessous)
3. un rectangle en un triangle équilatéral (animation 3 ci-dessous)

Voici l’animation 2 (vous pouvez changer la valeur 1.6 de $l$ en une valeur entre 0.27 et 2, vous pouvez aussi changer le pas de 0.01 en 0.1) :

Pour réaliser une animation appuyer sur + puis sur - etc ...

Voici l’animation 3 (vous pouvez changer la valeur 1.6 de $a$ en une valeur entre 0.58 et 1.73, vous pouvez aussi changer le pas de 0.01 en 0.1) :

Pour réaliser une animation appuyer sur + puis sur - etc ...

2  Les 4 pièces du puzzle

Voici la décomposition du carré en 4 morceaux qui s’assemblent en formant le triangle équilatéral $R_1RR_2$ :

A:=point(0);B:=point(2);C:=point(2+2*i);D:=point(2*i);
M:=milieu(A,B);N:=milieu(C,D);la:=evalf(sqrt(4*sqrt(3)/3-1));
P:=point(i*(2-la));Q:=point(2+i*la);R:=rotation(M,pi/3,Q);
segment(P,N);segment(R,Q);segment(R,M);
segment(M,Q);segment(M,P);segment(N,Q);
N1:=symetrie(Q,N);R1:=symetrie(Q,R);
R2:=symetrie(M,R);P2:=symetrie(M,P);
segment(Q,R1);segment(R1,R2);
segment(M,R2);segment(B,P2);
C1:=symetrie(Q,C);segment(N1,C1);
affichage(polygone(A,M,R,P),1+rempli);
affichage(triangle(N,D,P),2+rempli);
affichage(polygone(C,N,R,Q),3+rempli);
affichage(polygone(B,M,R,Q),4+rempli);
polygone(M,P,N,Q);
R:=R;Q:=Q;M:=M;B:=B;C:=C;

okonload
Etant donné un carré, trouver la construction de ces pièces et prouvez que l’on a bien obtenu après réorganisation un triangle équilatéral.
La solution

Supposons le problème résolu
Si le carré est de côté 2a et le côté du triangle équilatéral est de côté 2b.
On doit avoir (égalité des aires) : $4a^2=b^2\sqrt 3$.
On voit que si les figures sont exactes pour obtenir un triangle équilatéral à partir du carré de côté 2a il faut, sans bouger la pièce bleue, faire subir :
- à la pièce rouge une symétrie par rapport à $M$
- à la pièce jaune une symétrie par rapport à $Q$
- à la pièce verte une translation de vecteur $NN_1$ ($N_1$ étant le symétrique de $N$ par rapport à $Q$).
Supposons que le triangle $R_1RR_2$ soit équilatéral.
On a alors :
$RQ=QR_1=b$, $RM=MR_2=b$, $MQ=R_1R_2/2=b$ et
Le triangle $RMQ$ est donc équilatéral.
$\widehat{QRN}=\widehat{QR_1N_1}=\pi/3$
$\widehat{PRM}=\widehat{P_2R_2M}=\widehat{QMR}=\pi/3$
Les droites $PN$, $MQ$ et $R_1R_2$ sont donc parallèles.
Puisque $PR=P_2R_2$, $RN=R_1N_1$ et $PN=P_2N_1$ on a :
$R_1R_2=2b=R_1N_1+N_1P_2+P_2R_2=RN+NP+PR=2NP$
Donc $NP=MQ=b$ et $MPNQ$ est un parallélogramme.
Puisque $PN=MQ$ et $DN=MB=a$, les triangles rectangles $DNP$ et $BMQ$ sont égaux, donc $PD=BQ$.
Les triangles rectangles $APM$ et $CQN$ sont aussi égaux ($AP=2a-l=CQ$).
On a :
$PN=MQ$ et $PM=NQ$ donc la quadrilatère $MPNQ$ est un parallélogramme.
Puisque $RMQ$ est un triangle équilatéral de côté $b$, on en déduit que la distance $h$ entre les parallèles $PN$ et $MQ$ vaut $b\sqrt 3/2$ ($h$ est la hauteur du triangle équilatéral $QRM$ de côté $b$).
Le point $R$ est donc l’intersection de la médiatrice de $MQ$ avec $PN$ et il est aussi le transformé de $Q$ par la rotation de centre $M$ et d’angle $\pi/3$.
Calculons $l=PD=BQ$.
Dans le triangle rectangle $DPN$, on a $PD=l$,$DN=a$ et $PN=b$,
donc :
$b^2=PN^2=l^2+a^2=4a^2/\sqrt(3)$ donc $l^2=b^2-a^2$
Donc $l^2=a^2(4\sqrt 3/3-1)$

La construction
Lorsque $PD=l=2a\sqrt{(\sqrt 3/3-1)}$, construisons :
le carré $ABCD$, _ le milieu $M$ (resp $N$) de $AB$ (resp $CD$)
le point $P$ (resp $Q$) du segment $AD$ (resp $BC$) tel que $DP=l$ (resp($BQ=l$)
Le point $R$ intersection de la médiatrice de $MQ$ avec $PN$
$R_2$ est le symétrique de $R$ par rapport à $M$ et
$R_1$ est le symétrique de $R$ par rapport à $Q$ donc
$MQ$ est parallèle à $R_1R_2=2b$ et $MQ=b$.
Les triangles rectangles $NDP$ et $MBQ$ sont donc égaux.
Donc $PD=BQ=l$, $PN=MQ$ et $DN=MB$
$A$ est le symétrique de $B$ par rapport à $M$ donc $AM=MB=a$
donc $AM=MB=DN=NC=a$.
Les triangles rectangles $APM$ et $CQN$ sont aussi égaux ($AP=2a-l=CQ$).
On a :
$PN=MQ$ et $PM=NQ$ donc la quadrilatère $MPNQ$ est un parallélogramme.
Remarque
$MPNQ$ n’est pas un rectangle car $MP^2+NP^2\neq 4$ :
evalf(longueur2(M,P)+longueur2(N,P)) ok

On a donc :
L’aire des triangles rectangles $APM$ et $CQN$ plus l’aire des triangles rectangles $NDP$ et $MBQ$ est égale à l’aire du rectangle $AMND$ c’est à dire est ègale à $2a^2$.
L’aire du parallélogramme $MPNQ$ vaut donc $4a^2-2a^2=2a^2$.
Puisque $MQ=b$ on en déduit que la distance $h$ entre les parallèles $PN$ et $MQ$ vaut $2a^2/b=b\sqrt 3/2$ (puisque $4a^2=b^2\sqrt 3$).
$h$ est la hauteur du triangle isocèle $RQM$ de base $QM=b$ donc
le triangle $QRM$ est équilatéral ($RQ^2=RM^2=h^2+(b/2)^2=b^2(3/4+1/4)=b^2$)

On tape pour avoir les pièces du puzzle (on prend pour simplifier $a=1$) i.e. le carré a des côtés de longueur 2 :

fonction pieces()
local l,M,N,P,Q,R,L;
L:=NULL;
l:=evalf(sqrt(4*sqrt(3)/3-1));
M:=point(1);
N:=point(1+2*i);
P:=point(i*(2-l));
Q:=point(2+i*l);
R:=inter_unique(droite(P,N),mediatrice(M,Q));
L:=L,affichage(quadrilatere(M,2,Q,R),4+rempli); 
L:=L,affichage(quadrilatere(Q,2+2*i,1+2i,R),3+rempli); 
L:=L,affichage(triangle(P,2i,1+2i),2+rempli);
L:=L,affichage(quadrilatere(0,M,R,i*(2-l)),1+rempli); 
retourne L;
ffonction :;

okonload
gl_ortho=1;pieces() ok

3  Le pavage correspondant au puzzle de Dudeney

On tape les procédures dudeney0 (la pièce triangle est en bas à gauche) et dudeney1 (la pièce triangle est en haut à droite) :

fonction dudeney0(z0)
local M,P,Q,R,l,L;
l:=sqrt(4*sqrt(3)/3-1);
M:=point(1+z0);
P:=point(2+i*(2-l)+z0);
Q:=evalf(point(i*l+z0));
L:=NULL;
R:=rotation(M,-pi/3,Q);
L:=L,affichage(quadrilatere(M,z0,Q,R),4+rempli); 
L:=L,affichage(quadrilatere(Q,2*i+z0,1+2*i+z0,R),3+rempli); 
L:=L,affichage(triangle(P,2+2i+z0,1+2*i+z0),2+rempli);
L:=L,affichage(quadrilatere(2+z0,M,R,i*(2-l)+z0+2),1+rempli); 
retourne L;
ffonction:;
fonction dudeney1(z0)
local M,N,P,Q,R,l,L;
l:=sqrt(4*sqrt(3)/3-1);
M:=point(1+z0+2*i);
N:=point(1+z0);
P:=point(i*(l)+z0);
Q:=evalf(point(2-i*l+2*i+z0));
L:=NULL;
R:=inter_unique(segment(P,N),mediatrice(M,Q));
L:=L,affichage(quadrilatere(M,2+z0+2*i,Q,R),4+rempli); 
L:=L,affichage(quadrilatere(Q,2+z0,1+z0,R),3+rempli); 
L:=L,affichage(triangle(P,z0,1+z0),2+rempli);
L:=L,affichage(quadrilatere(0+z0+2*i,M,R,i*(l)+z0),1+rempli); 
retourne L;
ffonction :;

okonload

gl_ortho=1;axes=0;la:=evalf(sqrt(4*sqrt(3)/3-1));dudeney1(0), dudeney0(-2*i),dudeney0(-2+2*i*(la-1)),dudeney1(-2-2*i+2*i*(la-1)) ok

4  Pour animer la transformation

fonction animtri(t)
local l,M,N,B,C,D1,P,Q,R,Q1,N1,B1,C1,N2,P3,P2,L,B,C,R1,P1;
l:=sqrt(4*sqrt(3.)/3-1);
B:=point(2);C:=point(2+2*i);
M:=point(1);N:=point(1+2*i);
P:=point(i*(2-l));
Q:=evalf(point(2+i*l));
R:=evalf(inter_unique(segment(P,N),mediatrice(M,Q)));
L:=NULL;
L:=L,affichage(quadrilatere(M,0,P,R),1+rempli); 
L:=L,affichage(rotation(M,t,evalf(quadrilatere(M,2,Q,R))),4+rempli);
Q1:=rotation(M,t,Q);
R1:=rotation(M,t,R);
N1:=rotation(M,t,N);
B1:=rotation(M,t,B);
C1:=rotation(M,t,C);
D1:=rotation(Q1,t,rotation(M,t,point(2*i)));
P1:=rotation(Q1,t,rotation(M,t,P));
N2:=rotation(Q1,t,N1);
P3:=quadrilatere(Q1,R1,N1,C1);
L:=L,affichage(rotation(Q1,t,P3),3+rempli); 
P2:=triangle(P1,D1,N2);
L:=L,affichage(rotation(N2,t,P2),2+rempli);
return L;
ffonction:;

okonload
Voici l’animation :

Pour réaliser une animation appuyer sur + puis sur - etc ...

5  Prolongement : transformer un carré en un triangle isocèle

On peut faire la même construction en faisant varier $l$ entre 0 et $2a$, avec comme condition : le point $R$ se trouve sur le segment $PN$ si $l\neq 0)$.
On transformera ainsi, un carré de côté $2a$, en un triangle isocèle de base $2b=\sqrt{a^2+l^2}$ et de hauteur $h=4a^2/b$.
On a $0<=l<=2$.
Si $l=0$, le point $R$ est l’intersection de la médiatrice de $MB$ avec $DC$.
Si $l\neq 0$, pour que $R$ soit sur sur le segment $PN$ il faut que :
re(affixe(R)] soit entre 0 et $a=1$ et
im(affixe(R)] soit entre 0 et $2a=2$.
On choisit ici $a=1$ et on tape :

fonction affixeR()
local M,N,P,Q,R,l,zR;
purge(l);
M:=point(1);
N:=point(1+2*i);
P:=point(i*(2-l));
Q:=point(2+i*l);
R:=inter_unique(mediatrice(M,Q),droite(P,N));
zR:= affixe(R);
return simplify(re(zR)),simplify(im(zR));
ffonction :;

okonload
xR,yR:=affixeR() ok

solve((1>=xR and 2>=yR) and (l>=0 and 2>=l),l) ok

puisque $0\leq l\leq 2=2a$,il faut donc choisir : $(2-\sqrt 3)a\leq l \leq2a$.
Les triangles isocèles ont comme base $b=\sqrt{a^2+l^2}$ et une aire de $a^2=h*b/2$ donc la hauteur $h$ vaut $h=2a^2/b$.
Soit $t=(\overrightarrow{MQ}\overrightarrow{MP})$. $\tan(t)=2h/b$ on a donc :
$\tan(t)=\frac{4a^2}{a^2+l^2}$ donc
$4/5\leq tan(t) \leq 4/(3-\sqrt 3)$ soit :
$\atan(4/5) \leq t \leq atan(4/(3-sqrt(3)))$.
Voici la fonction pour animer la transformation :

fonction animtransfo(l)
local M,N,B,C,D1,P,Q,R,Q1,N1,B1,C1,N2,P3,P2,L,B,C,R1,R2,P1;
B:=point(2);C:=point(2+2*i);
M:=point(1);N:=point(1+2*i);
P:=point(i*(2-l));
Q:=evalf(point(2+i*l));
R:=inter_unique(mediatrice(M,Q),droite(P,N));
L:=affichage(quadrilatere(M,0,P,R),1+rempli); 
L:=L,affichage(rotation(M,pi,evalf(quadrilatere(M,0,P,R))),1+rempli);
N1:=symetrie(Q,N);R1:=symetrie(Q,R);
C1:=symetrie(Q,C);segment(N1,C1);
R1:=symetrie(Q,R);
R2:=symetrie(M,R);
P2:=symetrie(M,P);
L:=L,affichage(polygone(2,M,R,Q),4+rempli);
L:=L,affichage(polygone(P,2*i,N),2+rempli);
L:=L,affichage(polygone(P2,C1,N1),2+rempli)
L:=L,affichage(polygone(0,P,R,,M),1+rempli); 
L:=L,affichage(polygone(B,P2,R2,,M),1+rempli); 
L:=L,affichage(polygone(N,R,Q,C),3+rempli);
L:=L,affichage(polygone(N1,R1,Q,C1),3+rempli);
return L;
ffonction:;

okonload

Voici l’animation quand $l$ varie entre 0 et 2 :

Pour réaliser une animation appuyer sur + puis sur - etc ... On voit que si $l$ est entre entre 0 et $2-\sqrt 3\simeq 0.267949192431$ ca ne marche pas ! Mais la construction reste valable pour $l=0$ (on notera dans ce cas la disparition du triangle vert).
On peut faire aussi l’animation qui transforme le carré en un triangle isocèle.

fonction animtriso(t,l)
local M,N,B,C,D1,P,Q,R,Q1,N1,B1,C1,N2,P3,P2,L,B,C,R1,P1;
//l:=sqrt(4*sqrt(3.)/3-1);
B:=point(2);C:=point(2+2*i);
M:=point(1);N:=point(1+2*i);
P:=point(i*(2-l));
Q:=evalf(point(2+i*l));
R:=evalf(inter_unique(segment(P,N),mediatrice(M,Q)));
L:=NULL;
L:=L,affichage(quadrilatere(M,0,P,R),1+rempli); 
L:=L,affichage(rotation(M,t,evalf(quadrilatere(M,2,Q,R))),4+rempli);
Q1:=rotation(M,t,Q);
R1:=rotation(M,t,R);
N1:=rotation(M,t,N);
B1:=rotation(M,t,B);
C1:=rotation(M,t,C);
D1:=rotation(Q1,t,rotation(M,t,point(2*i)));
P1:=rotation(Q1,t,rotation(M,t,P));
N2:=rotation(Q1,t,N1);
P3:=quadrilatere(Q1,R1,N1,C1);
L:=L,affichage(rotation(Q1,t,P3),3+rempli); 
P2:=triangle(P1,D1,N2);
L:=L,affichage(rotation(N2,t,P2),2+rempli);
return L;
ffonction:;

okonload
Voici l’animation (vous pouvez changer la valeur 1.6 de $l$ en une valeur entre 0.27 et 2) :

Pour réaliser une animation appuyer sur + puis sur - etc ...

6  Prolongement : transformer un rectangle en un triangle équilatéral

Peut-on transformer un rectangle $c \times a$ en un triangle équilatéral avec la méthode de Dudeney ?
On a vu précédemment que pour que la méthode de Dudeney fonctionne il fallait avoir soit $l=0$, soit le point $R$ sur le segment $PN$ ($R$ est l’intersection de la médiatrice de $MQ$ et du segment $PN$, $MQNP$ est un parallélogramme et $MQ=L=\sqrt{c^+l^2}$).

6.1  Valeur de $l$ pour transformer un rectangle $2c\times 2a$ en un triangle équilatéral

Pour trouver la valeur de $l$ il suffit d’égaler la surface d’un triangle équilatéral de côté $b=\sqrt(c^2+l^2)$ avec la surface d’un rectangle de côté $c\times a$.
On doit donc avoir :
$b^2\sqrt 3/4=(c^2+l^2)\sqrt 3/4=ac$ Donc $l^2+c^2=4ac/\sqrt 3$ donc $l^2=c/\sqrt 3(4a-c\sqrt 3)$.
Cas particuler $l=0$
$l=0$ est équivalent à $a=c\sqrt 3/4$ et dans se cas le puzzle se réduit à 3 pièces :
On peut supposer, quitte à faire une homothetie, que $c=1$.

fonction dudeneyrect0()
local a,l,M,N,B,C,P,Q,R,Q1,N1,B1,C1,N2,P3,P2,L,B,C,R1,R2,P1;
a:=sqrt(3)/4;l:=0;
B:=point(2);C:=point(2+2a*i);
M:=point(1);N:=point(1+2a*i);
P:=point(i*(2a-l)):;
Q:=evalf(point(2+i*l));
R:=inter_unique(mediatrice(M,Q),droite(P,N));
L:=NULL;
L:=L,affichage(quadrilatere(M,0,P,R),1+rempli); 
L:=L,affichage(rotation(M,pi,evalf(quadrilatere(M,0,P,R))),1+rempli);
N1:=symetrie(Q,N);R1:=symetrie(Q,R);
C1:=symetrie(Q,C);segment(N1,C1);
R1:=symetrie(Q,R);
R2:=symetrie(M,R);
P2:=symetrie(M,P);
L:=L,affichage(polygone(2,M,R,Q),4+rempli);
L:=L,affichage(polygone(P,2*a*i,N),2+rempli);
L:=L,affichage(polygone(P2,C1,N1),2+rempli)
L:=L,affichage(polygone(0,P,R,,M),1+rempli); 
L:=L,affichage(polygone(B,P2,R2,,M),1+rempli); 
L:=L,affichage(polygone(N,R,Q,C),3+rempli);
L:=L,affichage(polygone(N1,R1,Q,C1),3+rempli);
retourne L;
ffonction :;

okonload
dudeneyrect0() ok

6.2  Les conditions sur $a$ et $c$

Cherchons les conditions pour que $R$ soit entre $P$ et $N$.
Pour simplifier, on peut supposer, quitte à faire une homothetie que $c=1$. Pour que $R$, d’affixe $xR+i*yR$, soit entre $P$ et $N$, il faut et il suffit que :
$0\leq xR \leq 1$ et $0\leq yR<2a$
Soit zP,zN,zQ,zM les affixes de P,N,Q,M.
Cherchons les coordonnèes $xR$ et $yR$ du point $R$, pour cela on demande à Xcas (on peut bien sûr faire les calculs à la main !) :

fonction coordR()
local P,Q,M,N,a,l2,l,R;
purge(a);
l2:=4a/sqrt(3)-1;
l:=sqrt(abs(l2));
P:=point((2a-l)*i);
Q:=point(2+l*i);
M:=point(1);
N:=point(1+2*a*i);
R:=inter_unique(droite(P,N),mediatrice(Q,M));
retourne coordonnees(R)
ffonction:;

okonload
Puis on cherche les coordonnées de $R$ et on résout les inéquations $0\leq xR \leq 1$ et $0\leq yR<2a$ ;
:
xR,yR:=subst(coordR(),abs(4*a/sqrt(3)-1),4*a/sqrt(3)-1):; simplify(solve(xR>= 0 and 1>=xR,a));simplify(solve(2a>=yR and yR>= 0,a)); ok

Donc, puisque $\frac{\sqrt 3}{3}\leq a$ implique que $\frac{\sqrt 3}{4}\leq a$, on pourra transformer un rectangle $1 \times a$ en un triangle équilatéral avec la méthode de Dudeney si et seulement si on a : $$\frac{\sqrt 3}{3}\leq a\leq \sqrt 3 )$$ ou encore :
On pourra transformer un rectangle $c \times a$ en un triangle équilatéral avec la méthode de Dudeney si et seulement si on a : $$\frac{c\sqrt 3}{3}\leq a \leq c\sqrt 3$$ ou encore $$\frac{c\sqrt 3}{3}\leq a \leq c\sqrt 3$$ On pourra donc aussi transformer un rectangle $c \times a$ en un triangle équilatéral avec la méthode de Dudeney si et seulement si on a : $$\frac{a\sqrt3}{3}\leq c \leq a\sqrt 3$$ ce qui signifie que l’on pourra avoir 2 puzzles différents.

Autre méthode On choisit $a=3/2$, $c=1$ et $l=\sqrt{4a*c/\sqrt 3-c^2}\simeq 1.57$

Mr:=point(1);Qr:=point(2+1.57*i);
Nr:=point(1+3*i);Pr:=point((3-1.57)*i);
affichage(polygone(0,2,2+3*i,3*i),epaisseur_ligne_2);
affichage(polygone(Mr,Qr,Nr,Pr),epaisseur_ligne_2);
triangle_equilateral(Mr,Qr,Rr);
affichage(parallelogramme(Rr,Mr,Qr),1);
affichage(parallelogramme(Mr,Qr,Rr),4);
angle(Mr,Qr,Pr,"t");
affichage(angle(Qr,Rr,Mr,"\pi/3"),4);

okonload
Pour que la construction soit possible il faut que l’on puisse inscrire le triangle équilatéral $M_rQ_rR_r$ dans le parallélogramme $M_rQ_rN_rP_r$ : la hauteur $h$ Le triangle $MQR$ a comme côté $M_rQ_r=\sqrt{c^2+l^2}$ et comme hauteur $h=\sqrt{c^2+l^2}\sqrt 3/2$.
Il faut et il suffit que :
$\pi/3\leq t=\overrightarrow{M_rQ_r}\overrightarrow{M_rP_r}\leq 2\pi/3$ ce qui équivalent à :
$\sqrt(3)/2\leq \sin(t)\leq 1$
ce qui équivalent à :
$3/4\leq \sin(t)^2\leq 1$
On a $MP^2=c^2+(2a-l)^2=4a^2-4al+l^2+c^2$ donc :
$\sin(t)^2=\frac{h^2}{MP^2}=\frac{3}{4}\frac{c^2+l^2}{4a^2-4al+l^2+c^2}$
La condition s’écrit alors :
$\frac{3}{4}\leq \frac{3}{4}\frac{c^2+l^2}{4a^2-4al+l^2+c^2}$
$4a^2-4al+l^2+c^2\leq c^2+l^2$
ou encore :
$a\leq l$ et $a^2+c^2\leq l^2+c^2=4ac/\sqrt 3$
La condition devient donc :
$a^2-4ac/\sqrt 3+c^2\leq 0$
En posant $k=a/c$, il faut résoudre l’inéquation :
$k^2-4k/\sqrt 3 +1\leq 0$ donc il faut que $k$ soit compris entre les 2 racines de $k^2-4k/\sqrt 3 +1=0$ qui sont :
$k1=1/\sqrt 3$ et $k2=\sqrt 3$.
La condition pour que le puzzle soit possible est donc : $$\frac{1}{\sqrt 3}\leq \frac{a}{c}\leq \sqrt 3$$ ou encore : $$\frac{c}{\sqrt 3}\leq a\leq c\sqrt 3c$$

6.3  La transformation

Cas général $c/\sqrt 3\leq a\leq c\sqrt 3$
$l$ est défini par :
l=sqrt(4ac/sqrt(3)-c^2) car $4ac > 4c^2/\sqrt 3>c^2\sqrt 3$
On a alors : $$l=\sqrt{\frac{4ac}{\sqrt 3}-c^2}$$ Lorsque le triangle $RMQ$ est équilatéral sa hauteur est :
$h=\sqrt{3(l^2+1)}/2$.
Donc lorsque le triangle $RMQ$ est équilatéral, la hauteur du paraléllogramme $MQNP$ est $h=\sqrt{3(l^2+1)}/2$.
Pour l’animation, on choisit $c=1$ et on fait varier $a$ entre $1/\sqrt 3$ et $\sqrt 3$ :

fonction dudeneyrect(a,c)
  local L,A,B,C,C1,D,M,N,N1,P,P2,Q,R,R1,R2,l; 
  l:=evalf(sqrt(4a*c/sqrt(3)-c^2));
  L:=NULL;  
  A:=point(0);  
  B:=point(2*c);  
  C:=point(2*c+2*a*i);  
  D:=point(2*a*i);  
  //polygone(A,B,C,D);  
  P:=point((2*a-l)*i);  
  Q:=point(2*c+l*i);  
  M:=point(c);  
  N:=point(c+2*a*i);  
  R:=inter_unique(mediatrice(M,Q),segment(N,P));  
  L:=L,affichage(triangle(D,P,N),2+rempli);  
  L:=L,affichage(polygone(A,P,R,M),1+rempli);  
  L:=L,affichage(polygone(C,N,R,Q),3+rempli);  
  L:=L,affichage(polygone(B,M,R,Q),4+rempli);  
  R2:=symetrie(M,R);  
  P2:=symetrie(M,P);  
  N1:=symetrie(Q,N);  
  C1:=symetrie(Q,C);  
  R1:=symetrie(Q,R);  
  L:=L,affichage(polygone(C1,N1,R1,Q),3+rempli);  
  L:=L,affichage(polygone(B,P2,R2,M),1+rempli);  
  L:=L,affichage(triangle(C1,P2,N1),2+rempli);  
  retourne L;  
ffonction :;

okonload
On peut echanger le role de $a$ et $c$, on tape ($t$ désigne une translation qui permet de faire les 2 dessins sur la même figure).

fonction dudeneyrect1(t,a,c)
 local L,A,B,C,C1,D,M,N,N1,P,P2,Q,R,R1,R2,l;
l:=evalf(sqrt(4a*c/sqrt(3)-c^2));
L:=NULL;    
A:=point(t);B:=point(t+2*c);C:=point(t+2c+2a*i);D:=point(t+2a*i);
//polygone(A,B,C,D);
P:=point(t+(2a-l)*i);Q:=point(t+2c+l*i);
M:=point(t+c);N:=point(t+c+2*a*i);
R:=inter_unique(mediatrice(M,Q),segment(N,P));
L:=L,affichage(triangle(D,P,N),2+rempli);
L:=L,affichage(polygone(A,P,R,M),3+rempli);
L:=L,affichage(polygone(C,N,R,Q),1+rempli);
L:=L,affichage(polygone(B,M,R,Q),4+rempli);
R2:=symetrie(M,R);
P2:=symetrie(M,P);
N1:=symetrie(Q,N);
C1:=symetrie(Q,C);
R1:=symetrie(Q,R);
L:=L,affichage(polygone(C1,N1,R1,Q),1+rempli);
L:=L,affichage(polygone(B,P2,R2,M),3+rempli);
L:=L,affichage(triangle(C1,P2,N1),2+rempli);
retourne L;
ffonction :;

okonload
Voici l’animation :

Cela donne 2 puzzles différents (sauf lorsque $a=c$ ou $a=c\sqrt 3$ ou $a=c/\sqrt 3$).
Les voilà en superposition :

fonction dudeneyrect2(a,c) 
  local L1,L2,A,B,C,D,M1,M2,N2,N1,P1,P2,Q1,Q2,R1,R2,l1,l2;
  l1:=sqrt(4a*c/sqrt(3)-c^2);
  l2:=sqrt(4a*c/sqrt(3)-a^2);
  L1:=NULL; L2:=NULL; 
  A:=point(0);  
  B:=point(2*c);  
  C:=point(2*c+2*a*i);  
  D:=point(2*a*i);    
  P1:=point((2*a-l1)*i);  
  Q1:=point(2*c+l1*i);  
  M1:=point(c);  
  N1:=point(c+2*a*i);  
  R1:=inter_unique(mediatrice(M1,Q1),segment(N1,P1));  
  P2:=point(l2+2a*i);  
  Q2:=point(2c-l2);  
  M2:=point(2*c+a*i);  
  N2:=point(a*i);  
  R2:=inter_unique(mediatrice(M2,Q2),segment(N2,P2));  
  L1:=L1,polygone(M1,B,Q1,R1);
  L1:=L1,segment(P1,N1);
  L2:=L2,polygone(M2,B,Q2,R2);
  L2:=L2,segment(P2,N2);
  return affichage(L1,1),affichage(L2,4),polygone(A,B,C,D);
ffonction:;

okonload

On peut faire aussi l’animation qui transforme le rectangle en un triangle équilatéral.

fonction animrectr(t,a)
local l,M,N,B,C,D1,P,Q,R,Q1,N1,B1,C1,N2,P3,P2,L,B,C,R1,P1;
l:=evalf(sqrt(4a/sqrt(3)-1));
B:=point(2);C:=point(2+2a*i);
M:=point(1);N:=point(1+2a*i);
P:=point(i*(2a-l));
Q:=evalf(point(2+i*l));
R:=evalf(inter_unique(segment(P,N),mediatrice(M,Q)));
L:=NULL;
L:=L,affichage(quadrilatere(M,0,P,R),1+rempli); 
L:=L,affichage(rotation(M,t,evalf(quadrilatere(M,2,Q,R))),4+rempli);
Q1:=rotation(M,t,Q);
R1:=rotation(M,t,R);
N1:=rotation(M,t,N);
B1:=rotation(M,t,B);
C1:=rotation(M,t,C);
D1:=rotation(Q1,t,rotation(M,t,point(2a*i)));
P1:=rotation(Q1,t,rotation(M,t,P));
N2:=rotation(Q1,t,N1);
P3:=quadrilatere(Q1,R1,N1,C1);
L:=L,affichage(rotation(Q1,t,P3),3+rempli); 
P2:=triangle(P1,D1,N2);
L:=L,affichage(rotation(N2,t,P2),2+rempli);
return L;
ffonction:;

okonload
Voici l’animation (vous pouvez changer la valeur 1.6 de $a$ en une valeur entre 0.58 et 1.73) :

Pour réaliser une animation appuyer sur + puis sur - etc ...

Clone Clear + - ->   Restart Exec. all